[스프레드시트 실습] 배열 수식의 활용

스프레드시트 실습

배열 수식의 활용

개념

• 바로가기

 

문제

다음 표에 표시된 부분의 값을 배열 수식을 이용하여 계산하시오.

 

배열 수식 적용 전

배열 수식 적용 후

해설

① 건물번호별 임대건수(C2)

• SUM(($B$9:$B$23=B2)*1)를 입력한 후 [Ctrl] + [Shift] + [Enter]를 누름.

조건이 1개일 때, 배열 수식을 이용하여 개수를 구하는 방법

• 방법 1
  • {=SUM( (조건1) * 1 )}
• 방법 2
  • {=SUM( IF(조건1, 1) )}
• 방법 3
  • {=COUNT( IF(조건1, 1) )}

1. 조건과 범위 찾기

• 조건
  • 건물번호별이란 조건은, 비교 대상이 될 건물번호가 있는 범위와 비교할 기준이 되는 건물번호(B2)를 =으로 연결하여 적어주면 됨.
  • 여러 개의 값을 구하는 수식이므로 범위를 절대 참조로 지정하여 $B$9:$B$23=B2로 지정함.

2. 위의 조건을 개수 구하기 배열 수식에 대입하기

• 방법 1
  • =SUM( ($B$9:$B$23=B2) * 1 )
• 방법 2
  • =SUM( IF($B$9:$B$23=B2, 1) )
• 방법 3
  • =COUNT( IF($B$9:$B$23=B2, 1) )

3. [Ctrl] + [Shift] + [Enter] 누르기

• 방법1, 2,, 3을 입력한 후 [Ctrl] + [Shift] + [Enter]를 누르면 수식의 앞뒤에 중괄호 {}가 표시됨.

 

② 건물변호별 계약면적(D2)

• =SUM(($B$9:$B$23=B2)*$E$9:$E$23)를 입력한 후 [Ctrl] + [Shift] + [Enter]를 누름.

조건이 1개일 때, 배열 수식을 이용하여 합계 구하는 방법

• 방법 1
  • {=SUM( (조건) * (합계를_구할_범위) ) }
• 방법 2
  • {=SUM( IF( 조건, 합계를_구할_범위 ) )}

 

③ 건물번호별 평균 월임대료(E2)

• =AVERAGE(IF($B$9:$B$23=B2, $F$9:$F$23))를 입력한 후 [Ctrl] + [Shift] + [Enter]를 누름.

조건이 1개일 때, 배열 수식을 이용하여 평균 구하는 방법

• {=AVERAGE( IF(조건, 평균을_구할_범위) }

 

④ 건물번호별 최소 임대가격(F2)

• =MIN(IF($B$9:$B$23=B2, $D$9:$D$23))를 입력한 후 [Ctrl] + [Shift] + [Enter]를 누름.

조건이 1개일 때, 배열 수식을 이용하여 최소값 구하는 방법

• {=MIN( IF(조건, 최소값을_구할_범위) }

 

⑤ 건물번호별 최대 임대가격(G2)

• =MAX(($B$9:$B$23=B2)*$D$9:$D$23)를 입력한 후 [Ctrl] + [Shift] + [Enter]를 누름.

조건이 1개일 때, 배열 수식을 이용하여 최대값 구하는 방법

• 방법 1
  -{=MAX( (조건) * (최대값을_구할_범위) )}
• 방법 2
• {=MAX( IF(조건, 최대값을_구할_범위) }}

 

⑥ 건물번호별 월 임대료가 1,000,000원 이상인 임대건수(H2)

• =SUM(($B$9:$B$23=B2)*($F$9:$F$23>=1000000))를 입력한 후 [Ctrl] + [Shift] + [Enter]를 누름.

조건이 2개일 때, 배열 수식을 이용하여 최대값 구하는 방법

• 방법 1
  • {=SUM( (조건1) * (조건2) )}
• 방법 2
  • {=SUM( IF(조건1, IF(조건2, 1) ) )}
• 방법 3
  • {=COUNT( IF( (조건1) * (조건2), 1) )}